#!/usr/bin/perl

# SYNOPSIS: Hypertize text url list to html.
# AUTHOR: Mohsin_Ahmed http://www.cs.albany.edu/~mosh
# DOC: ~/init/index.txt is ascii files of urls.
#    o SECTION:           becomes bold faced SECTION title.
#    o TEXT: URL COMMENT  becomes a table of |TEXT|URL|COMMENT|
#    o       URL =PTR COMMENT       also add PTR as quickref at top.
#    o Backslash newline to break up long urls.
#    o Blank lines ignored
#    o # lines are comments, ignored.
#    o ========= becomes <hr> or '-----' in the table.

$USAGE = '
USAGE: url2html urlfile.txt         ... prints html file on stdout
       url2html index.txt > index.htm
       url2html start.txt > start.htm
    Redirection does not work with in command.com/bat, use cmd95.exe
OPTIONS:
    -h          Help
    -plain      No tables in html file.
';


while( $_ = $ARGV[0],  m/^-/ ){ shift;
        if(     m/^--$/   ){ last;
        }elsif( m/^-plain/  ){  $do_plain++;
        }elsif( m/^-[h?]/ ){ die $USAGE;
        }elsif( m/^-v/    ){ $verbose++;
        }else{ die "Unknown option '$_'\n";
        }
}

die $USAGE . "Need an input file.\n" unless @ARGV;

my $blankcol = "<td></td>";
my( $url_count, $nntp_count );
my @htmlfile;  # The whole html file is first built then printed.
my %quicker;   # urls prefixed with = are added to quickref.
my @section;

INLINE: while(<>){

    while( s,\\\s*$,, && ! eof() ){     # Join \ Lines.
        my $nextline;
        $nextline = <>;           # spaces before '\' are preserved.
        $nextline =~ s/^\s*//;    # spaces after '\' are removed.
        $_ .= $nextline;          # join lines, now fall thru.
    }

    if( m/^#/ ){                  # mhtml only comments.
        next INLINE;
    }
    s/\s\#\s.*\n/\n/;             # eg. ftp:xyz   # comment passwd is xy

    if( $do_plain ){
        if( eof() ){ die "Done plain $. lines to urls.\n"; }

        # Hypertize File URLs.
        s!(\w+):\s*((file):[\\/]*(\S+))
            !\n\t<a href="$2">$1</a>\n
            !gix;

        s!\s((file):[\\/]*(\S+))
            !\n\t<a href="$1">$3</a>\n
            !gix;

        # Hypertize 'title: URL'.
        s!(\w+):\s*((http|ftp|news):[/\\]*(\S+))
            !\n\t<a href="$2">$1</a>\n
            !gix;

        # '<space> URL'
        s!(\s|^)((http|ftp|news):[/\\]*(\S+))
            !\n\t<a href="$2">$4</a>\n
            !gix;

        next INLINE if m/^\s*$/;         # skip blank lines.

        print $_, "<br>\n";                 # Print regardless.
        next INLINE;
    }


    if( ! $tabled++ ){
        push @htmlfile,  "<table>\n";       # start a new table.
        # "<center> <TABLE WIDTH=90% CELLPADDING=4 BORDER=2>\n";
    }

    if( m/^[-=]{30,}$/ ){          # "-----------" are tablified.
        push @htmlfile, "<tr><td>", '_'x15, "</td>",
                  "<td>", '_'x50, "</td>","</tr>\n";
        next INLINE;
    }elsif( m/^\s*$/ ){         # ignore blank lines.
        next INLINE;
    }elsif( m/^\s*(.*)                                # title $1
         ((file|http|ftp|mailto|news|telnet): \S+)\s* # proto: url $2 $3
         (=(\S*))?                                    # quickref $5
         (.*)$                                        # comment  $6
        /x
    ){
        my $title   = $1; #   || "NO-TITLE";
        my $url     = $2;
        my $isquick = $4;
        my $ptquick = $5;
        my $comment = $6;
        my $showurl = $url;

        # Netscape cannot handle very large tables.
        $url_count++;
        if( ($url_count % 100) == 99 ){
            push @htmlfile, "</table></center><hr>\n";  # end of table.
            push @htmlfile, "<table>\n";           # start a new table.
        }

        if( $url =~ s/file://i ){
            # pic: file:///e:/pic => e:/pic, remove extra slashes
            $showurl =~ s,file:[/\\]*,,;
        }

        # vim: http://www.vim.org => make title 'vim' clickable.
        # news: http://www.news.com/abc => news/abc
        # $showurl =~ s@(http|ftp)://(www\.)?(\w+)\.(org|com)\b$@$3@,gi;


        $comment =~ s/:?\s*$//;
        $comment = "($comment)" if $comment;

        push @htmlfile, "<tr>",
              "<td> $title                        </td>\n",
              "<td> <a href=\"$url\"> $showurl </a> $comment </td>\n",
              "</tr>\n";

        if( $isquick ){
            # push @quickref, "<a href=\"$url\"> $ptquick </a>|\n";
            $quicker{$ptquick} = $url;
        }

        next INLINE;

    }elsif( m/^(.*):\s*$/ ){       # 'Section:' is bold faced.
        my $sectionname = $1;
        push @section ,
          "<a href=\"\#section_$sectionname\">$sectionname</a>|\n";
    
        push @htmlfile, "\n\n",
          "<tr> <td>",
            "<a name=\"section_$sectionname\"> <b> $sectionname </b> </a>\n",
              "<a href=\"\#section_sectiontop\">:</a>\n", # colon => top
                "</td> <td> </td> </tr>\n";        
        next INLINE;
    }elsif( m/^(.*):\s*(.+)$/ ){       # 'Text: Info'.
        push @htmlfile, "<tr><td> $1: </td><td> $2 </td></tr>\n";
        next INLINE;
    }elsif( m/^(\S*)$/ ){           # word at line beginning
        push @htmlfile, "<tr> <td> <b> $1 </b> </td> $blankcol </tr>\n";
        next INLINE;
    }else{                          # words inside line.
        chomp;
        push @htmlfile, "<tr> $blankcol <td> $_ </td> </tr>\n";
        next INLINE;
    }
}

push @htmlfile, "</table></center><hr>\n";  # end of table.
push @htmlfile, timestamp(), "\n";      # timestamp at end of file.

# ===================================================
# start printing.

print "<a name=\"section_sectiontop\"></a> \n";

if( %quicker ){
    print "Quickref:\n";
    foreach $key ( sort {lc($a) cmp lc($b)} keys %quicker ) {
    print "<a href=\"$quicker{$key}\"> $key </a> | \n";
    }
}

if( @section ){
    print "\n<hr>\n Sections:";

    # Highlight each section alphabet (9)95/NT(A)ADSL(B)Bombay..(Y)(Z)Zztops
    my( $charone, $chartwo );   
    foreach (sort @section) {
        $chartwo = ( $_ =~ m/section_(.)/)[0];
        unless( $charone eq $chartwo ){
            # Whenever first char changes, bold it.
            # s|\">(.)|\"><B>$1</B>|
            if( $charone =~ m/[a-z]/i ){
                # Print missing alphabets also, eg: (X)Xray(Y)(Z)Zztops.
                $charone++;
                foreach $charthree ($charone .. $chartwo ){
                    print "($charthree)";
                }
            }else{
                # Not a alphabet.
                print "($chartwo)";
            }
        }
        $charone = $chartwo;
        print;
    }

    print "\n<hr>\n";

    # Netscape cannot handle very large tables, so break it up
    # into smaller tables?
    # print  "<center><table CELLPADDING=4 BORDER=2>\n";
    # while( @section ){
    #     print "\t<tr>\n";
    #     foreach $i (1..8){
    #         print "\t\t<td>", shift(@section), "</td>\n";
    #     }
    #     print "\t</tr>\n";
    # }
    # print "</table></center><hr>\n\n";  # end of table.

}

print @htmlfile;
print "<a href=\"\#section_sectiontop\">top</a>\n";
warn "Processed $url_count urls, and matched $nntp_count newsgroups.\n";

# end of main ============================================


sub timestamp {
    my $user = $ENV{'LOGNAME'}  || $ENV{'USERNAME'} || 'root';
    my $domain= $ENV{'DOMAIN'};
    my $host = $ENV{'HOSTNAME'} || $ENV{'COMPUTERNAME'} ||
               $ENV{'HOST'};
       $host .=  '.' . $domain if $domain;
    my $today = localtime();
    return "Updated on $today by $user\@$host.\n";
}


# EOF